Zum Hauptinhalt springen

Verwalten von Casdoor mit Terraform

Dieses Handbuch erklärt, wie Sie die Objekte eines Casdoor-Servers als Code mit dem offiziellen Casdoor Terraform Provider verwalten, damit Sie die Konfiguration prüfen, versionieren und auf mehrere Umgebungen anwenden können.


Lernziele​

  • Konfigurieren Sie den Casdoor Terraform Provider.
  • Erstellen Sie Organisationen, Anwendungen, Benutzer und andere Objekte aus einer Terraform-Konfiguration.
  • Binden Sie bereits vorhandene Objekte in Terraform ein.
  • Verstehen Sie, welche Felder Terraform schreibt und welche es unberührt lässt.

Voraussetzungen​

  • Terraform oder OpenTofu
  • Eine laufende Casdoor-Instanz
  • Die Client-ID und das Client-Secret einer Casdoor-Anwendung. Um alle Organisationen zu verwalten, verwenden Sie eine Anwendung der built-in-Organisation, wie z. B. app-built-in.

Über den Provider​

Der Provider ruft die Casdoor API als Anwendung auf, mit der Client-ID und dem Client-Secret der Anwendung. Er unterstützt die folgenden Ressourcen:

ResourceCasdoor objectImport ID
casdoor_organizationOrganizationname
casdoor_applicationApplication, with its providersname
casdoor_userUserorganization/name
casdoor_providerProviderowner/name
casdoor_certCertowner/name
casdoor_roleRoleorganization/name
casdoor_permissionPermissionorganization/name
casdoor_groupGrouporganization/name

Der owner eines Providers oder Zertifikats ist admin für ein globales Objekt, das sich alle Organisationen teilen, oder der Name der Organisation, der es gehört.

Provider konfigurieren​

  1. Gehen Sie im Casdoor Admin Console zu Applications, öffnen Sie app-built-in und kopieren Sie dessen Client ID und Client secret.

  2. Deklarieren Sie den Provider in Ihrer Terraform-Konfiguration:

    terraform {
    required_providers {
    casdoor = {
    source = "casdoor/casdoor"
    }
    }
    }

    provider "casdoor" {
    endpoint = "https://door.casdoor.com"
    client_id = var.casdoor_client_id
    client_secret = var.casdoor_client_secret
    }

    Um das Secret aus der Konfiguration herauszuhalten, lassen Sie die Einstellungen weg und übergeben Sie sie stattdessen als Umgebungsvariablen:

    export CASDOOR_ENDPOINT=https://door.casdoor.com
    export CASDOOR_CLIENT_ID=<client ID>
    export CASDOOR_CLIENT_SECRET=<client secret>
    terraform init

Objekte erstellen​

  1. Fügen Sie Ressourcen zur Konfiguration hinzu. Das folgende Beispiel erstellt eine Organisation, ein Zertifikat, einen GitHub-Identitätsanbieter, eine Anwendung, die beide nutzt, einen Benutzer, eine Rolle und eine Berechtigung:

    resource "casdoor_organization" "acme" {
    name = "acme"
    display_name = "Acme"
    password_type = "bcrypt"
    country_codes = ["US"]
    }

    resource "casdoor_cert" "acme" {
    name = "cert-acme"
    crypto_algorithm = "RS256"
    bit_size = 4096
    expire_in_years = 20
    }

    resource "casdoor_provider" "github" {
    name = "provider-acme-github"
    category = "OAuth"
    type = "GitHub"
    client_id = var.github_client_id
    client_secret = var.github_client_secret
    }

    resource "casdoor_application" "portal" {
    name = "app-acme-portal"
    organization = casdoor_organization.acme.name
    cert = casdoor_cert.acme.name
    redirect_uris = ["https://portal.acme.example.com/callback"]

    providers = [
    {
    name = casdoor_provider.github.name
    owner = "admin"
    can_sign_in = true
    can_sign_up = true
    },
    ]
    }

    resource "casdoor_user" "alice" {
    owner = casdoor_organization.acme.name
    name = "alice"
    email = "alice@acme.example.com"
    password = var.alice_password
    }

    resource "casdoor_role" "admins" {
    owner = casdoor_organization.acme.name
    name = "admins"
    users = ["acme/alice"]
    }

    resource "casdoor_permission" "portal_admin" {
    owner = casdoor_organization.acme.name
    name = "portal-admin"
    roles = ["acme/admins"]
    resource_type = "Application"
    resources = [casdoor_application.portal.name]
    actions = ["Read", "Write"]
    effect = "Allow"
    }

    output "portal_client_id" {
    value = casdoor_application.portal.client_id
    }
  2. Vorschau der Änderungen anzeigen:

    terraform plan
  3. Änderungen übernehmen:

    terraform apply

Casdoor generiert die Client-ID und das Client-Secret der Anwendung. Die Ressource exportiert diese als client_id und client_secret, was als sensitiv markiert ist, sodass Sie sie an die Anwendung übergeben können, die Benutzer mit Casdoor anmeldet.

Vorhandene Objekte importieren​

Um ein Objekt, das in der Admin-Konsole erstellt wurde, unter Terraform zu verwalten, führen Sie terraform import mit der Import-ID aus der Ressourcentabelle aus:

terraform import casdoor_organization.acme acme
terraform import casdoor_application.portal app-acme-portal
terraform import casdoor_user.alice acme/alice
terraform import casdoor_provider.github admin/provider-acme-github

Nach einem Import schreibt der erste terraform apply die Attribute password und client_secret einmalig, da Terraform ihre aktuellen Werte nicht aus Casdoor lesen kann.

Verständnis der von Terraform geschriebenen Felder​

  • Attribute in der Konfiguration: Terraform schreibt sie nach Casdoor.
  • Felder, die in der Konfiguration nicht gesetzt sind: Sie behalten die Werte bei, die sie in Casdoor haben. Dies schließt Felder ein, die vom Anbieter noch nicht unterstützt werden. Eine Ressource kann daher einen Teil eines Objekts verwalten, das Sie auch in der Admin-Konsole bearbeiten.
  • Attribute, die Sie aus der Konfiguration entfernen: Sie behalten ihren letzten Wert in Casdoor bei.
  • Passwörter und Secrets: Casdoor gibt niemals Werte wie das password eines Benutzers oder das client_secret eines Anbieters zurück. Terraform erkennt keine Änderungen daran, die außerhalb von Terraform vorgenommen werden.

Siehe auch​